RI Apple Group Crate 001 Disk 135
Emulation Item Preview
Share or Embed This Item
RI Apple Group Crate 001 Disk 135
Notes
Disk info for disk135.dsk:
File Name: ri_apple_group_crate_001_disks_135/disk135.dsk
Disk Name: /SMC165A1/
Physical Size (bytes): 143360
Free Space (bytes): 5120
Used Space (bytes): 138240
Physical Size (KB): 140
Free Space (KB): 5
Used Space (KB): 135
Archive Order: DOS
Disk Format: ProDOS
Total Blocks: 280
Free Blocks: 10
Used Blocks: 270
Volume Access: Destroy Read Rename Write
Block Number of Bitmap: 6
Creation Date: 08/12/1993
File Entries Per Block: 13
File Entry Length (bytes): 39
Active Files in Root Directory: 15
Minimum ProDOS Version Required: 0
Volume Created By ProDOS Version: 5
Volume Name: SMC165A1
Disk directory for disk135.dsk:
ri_apple_group_crate_001_disks_135/disk135.dsk /SMC165A1/
* PRODOS SYS 035 11/02/1992 11/02/1992 17,128
* BASIC.SYSTEM SYS 021 12/06/1991 12/06/1991 10,240 A=$2000
FINDER.DATA FND 001 08/12/1993 08/12/1993 80
MAIN.HALL BAS 029 09/19/1990 09/19/1990 14,052 A=$0801
BEGINNERS.CAVE DIR 002 08/12/1993 04/30/1991 1,024
LEADIN BAS 001 01/11/1990 09/19/1990 27 A=$0801
REV.19SEP90 BAS 001 09/19/1990 09/19/1990 202 A=$0801
EAMON.NAME TXT 001 01/09/1988 09/19/1990 20
EAMON.ROOMS TXT 005 01/06/1990 09/19/1990 1,677
EAMON.ROOM.NAME TXT 005 01/06/1990 09/19/1990 1,684
EAMON.DESC TXT 037 01/06/1990 09/19/1990 79,513
MAIN.PGM BAS 032 09/19/1990 09/19/1990 15,839 A=$0801
FAST.START VAR 004 01/12/1990 09/19/1990 1,355 A=$80BA
MAKE.FAST.START BAS 001 01/12/1990 09/19/1990 397 A=$0801
MAKE.ARTS.MONS BAS 001 09/19/1990 09/19/1990 267 A=$0801
EAMON.PREFIX TXT 001 06/17/1991 09/19/1990 23
FRESH.MEAT TXT 001 06/17/1991 09/19/1990 102
FINDER.DATA FND 001 06/10/1991 06/10/1991 282
CHAR.FILE.MAINT BAS 028 02/11/1990 04/18/1990 13,614 A=$0801
CHARACTERS TXT 003 06/17/1991 04/18/1990 702 L=150
EAMON.MASTER BAS 009 09/19/1990 09/19/1990 3,594 A=$0801
EAMON.PIC BIN 017 05/15/1986 04/18/1990 8,192 A=$2000
FRONT.DESK BAS 009 01/23/1990 04/18/1990 3,770 A=$0801
NEW.CHARACTER BAS 012 01/12/1990 04/18/1990 5,370 A=$0801
REV.19SEP90 BAS 001 09/19/1990 09/19/1990 232 A=$0801
SNAPPY TXT 003 12/20/1989 04/18/1990 968
STARTUP BAS 001 09/11/1992 09/11/1992 27 A=$0801
THE.ADVENTURER TXT 001 09/11/1992 09/11/1992 7
ProDOS format; 5,120 bytes free; 138,240 bytes used.
Text found in disk135.dsk/CHAR.FILE.MAINT.bas:
10 REM CHARACTER FILE
12 REM MAINTENANCE
14 REM - BY -
16 REM THOMAS J. ZUCHOWSKI
18 REM WINSTON-SALEM, NC
20 REM DEC 1983
25 REM PRODOS UPDATE 1/23/90
26 REM REV.2/11/90
30 REM EAMON ADVENTURER'S GUILD7625 HAWKHAVEN DR.CLEMMONS, NC 27012
100 FOR I = 768 TO 777: READ N: POKE I,N: NEXT
110 DATA 104,168,104,166,223,154,72,152,72,96
120 D$ = CHR$(4): TEXT
130 S$ = " ": REM 7 SPACES
140 HOME : VTAB 10
150 PRINT D$"PREFIX": INPUT PX$
200 REM /// INPUT DATA FROM DISK
205 ONERR GOTO 215
210 PRINT D$"OPEN CHARACTERS,L150": PRINT D$"READ CHARACTERS,R0": INPUT NC: PRINT D$: POKE 216,0: GOTO 220
215 POKE 216,0: PRINT CHR$(7): INVERSE : PRINT "UNABLE TO LOAD CHARACTERS FILE": NORMAL : PRINT : GOTO 440
220 N = NC +10:FULL = N
230 DIM NA$(N),SEX$(N),GOLD(N),BANK(N),HD(N),AG(N),CH(N),SA%(4,N),WA%(5,N),AC(N),AE(N),WN$(4,N),WT%(4,N),WO%(4,N),WD%(4,N),WS%(4,N),UP(N),DD$(N)
235 IF NC = 0 THEN 420
240 FOR I = 1 TO NC
250 PRINT
260 PRINT D$;"READ CHARACTERS,R";I: INPUT NA$(I)
270 IF NA$(I) < >"" THEN 320
280 ONERR GOTO 10000
290 INPUT DD$(I): IF DD$(I) = "" THEN NA$(I) = "(BAD DATA IN FILE)": GOTO 400
300 DD = VAL(DD$(I)): IF DD$(I) < >"" AND DD = 0 THEN NA$(I) = "(DEAD)"
310 IF DD < >0 THEN HD(I) = DD: GOTO 330
320 INPUT HD(I)
330 INPUT AG(I): INPUT CH(I)
340 FOR J = 1 TO 4: INPUT SA%(J,I): NEXT : FOR J = 1 TO 5: INPUT WA%(J,I): NEXT
350 INPUT AE(I): INPUT SEX$(I): IF SEX$(I) = "M" OR SEX$(I) = "F" OR SEX$(I) = "" THEN 380
360 PRINT D$: PRINT D$;"READ CHARACTERS,R";I: INPUT NA$(I): INPUT DD$(I)
370 NA$(I) = "(DEAD)": GOTO 320
380 INPUT GOLD(I): INPUT BANK(I): INPUT AC(I)
390 FOR J = 1 TO 4: INPUT WN$(J,I): INPUT WT%(J,I): INPUT WO%(J,I): INPUT WD%(J,I): INPUT WS%(J,I): NEXT
400 NEXT I: PRINT D$
410 POKE 216,0: IF NC >0 THEN 510
420 HOME : VTAB 10
430 PRINT " THE CHARACTERS FILE IS EMPTY."
440 PRINT : PRINT S$;" YOUR ONLY OPTION IS TO": PRINT S$;" GENERATE A NEW CHARACTER.
450 PRINT : PRINT : PRINT S$;: INPUT " DO YOU WISH TO DO THIS?";A$: IF A$ = "Y" THEN 8000
460 GOTO 9050
500 REM /// MAIN MENU
510 TX$ = "":UP = 0: HOME : IF FULL = 0 THEN VTAB 8: PRINT " THE DIMENSIONED ARRAYS ARE FULL; THE CHARACTER ARRAYS ARE BEING SAVED TO DISK. RERUN THE PROGRAM TO CONTINUE.": GOTO 9000
520 HOME : PRINT SPC( 17);"EAMON": PRINT : PRINT " CHARACTER FILE MAINTENANCE": VTAB 6: PRINT S$;" CHARACTER: NONE";: IF C >0 THEN HTAB 21: PRINT NA$(C);" ";
530 VTAB 8: PRINT : PRINT " SELECT ACTION:": PRINT
540 PRINT S$;"1. SELECT A RECORD": PRINT S$;"2. MANIPULATE THIS RECORD": PRINT S$;"3. FILE MAINTENANCE"
550 PRINT S$;"4. TRANSFER THIS RECORD": PRINT S$;"5. GENERATE A NEW CHARACTER"
560 PRINT S$;"6. UPDATE RECORD AND QUIT":X = 6: GOSUB 600
570 ON S GOTO 1000,2000,6000,7000,8000,9000
600 REM /// GET NUMBER
610 PRINT : PRINT " INPUT (1-";X;"):";
620 GET A$:S = VAL(A$): IF S <1 OR S >X THEN 620
630 PRINT A$: RETURN
700 REM /// CONTINUE PROMPT
710 PRINT : PRINT " (PRESS ANY KEY TO CONTINUE)";: GET A$: PRINT : GOTO 510
720 PRINT : PRINT " (PRESS ANY KEY TO CONTINUE)";: GET A$: PRINT : RETURN
1000 REM /// SELECT RECORD
1010 HOME : VTAB 6: PRINT " SELECT RECORD BY:": PRINT : PRINT S$;"1. NAME": PRINT S$;"2. RECORD NUMBER": PRINT S$;"3. NEXT RECORD": PRINT S$;"4. RETURN TO MAIN MENU":X = 4: GOSUB 600: PRINT
1020 ON S GOTO 1100,1210,1300,510
1100 REM /// BY NAME
1110 INPUT "CHARACTER NAME:";NA$(0)
1120 FOR I = 1 TO NC: IF NA$(I) < >NA$(0) THEN NEXT : PRINT CHR$(7): PRINT "NO SUCH CHARACTER IN THIS FILE.": GOSUB 720: GOTO 1000
1130 C = I:C1 = C: GOTO 5000
1200 REM /// BY RECORD #
1210 INPUT "RECORD NUMBER:";C
1220 IF C >NC THEN PRINT CHR$(7): PRINT "ONLY ";NC;" RECORDS IN FILE.": GOSUB 720: GOTO 1000
1230 C1 = C: GOTO 5000
1300 REM /// NEXT RECORD
1310 IF C = NC THEN PRINT : PRINT SPC( 14);"END OF FILE.":C = 0: GOTO 710
1320 C = C +1: GOTO 5000
2000 REM /// MODIFY RECORD
2010 IF C = 0 THEN SUB = 1: GOSUB 1000
2020 NA$(0) = NA$(C):SEX$(0) = SEX$(C):GOLD(0) = GOLD(C):BANK(0) = BANK(C):HD(0) = HD(C):AG(0) = AG(C):CH(0) = CH(C)
2030 FOR I = 1 TO 4:SA%(I,0) = SA%(I,C): NEXT : FOR I = 1 TO 5:WA%(I,0) = WA%(I,C): NEXT
2040 AE(0) = AE(C):AC(0) = AC(C): FOR I = 1 TO 4:WN$(I,0) = WN$(I,C):WT%(I,0) = WT%(I,C):WO%(I,0) = WO%(I,C):WD%(I,0) = WD%(I,C):WS%(I,0) = WS%(I,C): NEXT
2050 DD$(0) = DD$(C)
2060 HOME : HTAB (40 - LEN(NA$(0)))/2: PRINT NA$(0): PRINT
2070 PRINT " INPUT FIELD TO CHANGE:": PRINT : PRINT S$;" 1. NAME": PRINT S$;" 2. HARDINESS": PRINT S$;" 3. AGILITY": PRINT S$;" 4. CHARISMA"
2080 PRINT S$;" 5. SPELL ABILITIES": PRINT S$;" 6. WEAPON ABILITIES": PRINT S$;" 7. ARMOR"
2090 PRINT S$;" 8. SEX": PRINT S$;" 9. GOLD": PRINT S$;"10. ARMOR EXPERTISE": PRINT S$;"11. WEAPON"
2100 PRINT S$;"--------------------": PRINT S$;"12. DISPLAY RECORD": PRINT S$;"13. RETURN TO MAIN MENU"
2110 PRINT S$;"14. ADD AS A NEW RECORD": PRINT S$;"15. CANCEL CHANGES": PRINT : INPUT " INPUT (1-15) ";S
2120 ON S GOSUB 2200,2400,2600,2800,3000,3200,3400,3600,3800,4000,4200,4400,4600,4800,510
2130 GOTO 2060
2200 IF DD$(0) < >"" THEN PRINT : PRINT "THIS CHARACTER IS DEAD. THE PREVIOUS NAME OF THIS CHARACTER WAS:": PRINT : HTAB 15: PRINT "(?)";DD$(0): PRINT : GOTO 2220
2210 PRINT : PRINT "OLD NAME: "NA$(0)
2220 INPUT "NEW NAME: ";X$: IF LEN(X$) = 0 OR LEFT$(X$,1) <"A" OR LEFT$(X$,1) >"Z" OR LEN(X$) >20 THEN PRINT : PRINT "INVALID NAME.": GOTO 2200
2230 FOR I = 1 TO NC: IF NA$(I) < >X$ THEN NEXT
2240 IF NA$(I) = X$ AND C < >I THEN PRINT : PRINT "THAT NAME IS ALREADY BEING USED.": GOTO 2200
2250 DD$(0) = "":UP = 1:NA$(0) = X$: RETURN
2400 PRINT : PRINT "OLD HARDINESS:";HD(0): INPUT "NEW HARDINESS:";X: IF X <3 OR X >300 OR X < > INT(X) THEN PRINT : PRINT "INVALID HARDINESS.": GOTO 2400
2410 UP = 1:HD(0) = X: RETURN
2600 PRINT : PRINT "OLD AGILITY:";AG(0): INPUT "NEW AGILITY:";X: IF X <3 OR X >300 OR X < > INT(X) THEN PRINT : PRINT "INVALID AGILITY.": GOTO 2600
2610 UP = 1:AG(0) = X: RETURN
2800 PRINT : PRINT "OLD CHARISMA:";CH(0): INPUT "NEW CHARISMA:";X: IF X <3 OR X >300 OR X < > INT(X) THEN PRINT : PRINT "INVALID CHARISMA.": GOTO 2800
2810 UP = 1:CH(0) = X: RETURN
3000 HOME : VTAB 8: PRINT " SELECT SPELL:": PRINT S$;"1. BLAST",SA%(1,0): PRINT S$;"2. HEAL",SA%(2,0): PRINT S$;"3. SPEED",SA%(3,0)
3010 PRINT S$;"4. POWER",SA%(4,0): PRINT S$;"----------": PRINT S$;"5. RETURN TO MENU":X = 5: GOSUB 600: PRINT : ON S GOTO 3020,3030,3040,3050,3060
3020 UP = 1: INPUT "NEW BLAST RATING:";SA%(1,0): GOTO 3000
3030 UP = 1: INPUT "NEW HEAL RATING:";SA%(2,0): GOTO 3000
3040 UP = 1: INPUT "NEW SPEED RATING:";SA%(3,0): GOTO 3000
3050 UP = 1: INPUT "NEW POWER RATING:";SA%(4,0): GOTO 3000
3060 RETURN
3200 HOME : VTAB 8: PRINT " SELECT WEAPON ABILITY:": PRINT S$;"1. AXE",WA%(1,0): PRINT S$;"2. BOW",WA%(2,0): PRINT S$;"3. CLUB",WA%(3,0)
3210 PRINT S$;"4. SPEAR",WA%(4,0): PRINT S$;"5. SWORD",WA%(5,0): PRINT S$;"----------": PRINT S$;"6. RETURN TO MENU":X = 6: GOSUB 600
3220 PRINT : ON S GOTO 3230,3240,3250,3260,3270,3280
3230 UP = 1: INPUT "NEW AXE EXPERTISE:";WA%(1,0): GOTO 3200
3240 UP = 1: INPUT "NEW BOW EXPERTISE:";WA%(2,0): GOTO 3200
3250 UP = 1: INPUT "NEW CLUB EXPERTISE:";WA%(3,0): GOTO 3200
3260 UP = 1: INPUT "NEW SPEAR EXPERTISE:";WA%(4,0): GOTO 3200
3270 UP = 1: INPUT "NEW SWORD EXPERTISE:";WA%(5,0): GOTO 3200
3280 RETURN
3400 UP = 1: HOME : PRINT " ARMOR CLASS:": PRINT : PRINT S$;"1. SHIELD ONLY": PRINT S$;"2. LEATHER ARMOR": PRINT S$;"3. LEATHER ARMOR & SHIELD": PRINT S$;"4. CHAIN ARMOR"
3410 PRINT S$;"5. CHAIN ARMOR & SHIELD": PRINT S$;"6. PLATE ARMOR": PRINT S$;"7. PLATE ARMOR & SHIELD"
3420 PRINT : PRINT S$;"(CURRENTLY ";AC(0);")":X = 7: GOSUB 600:AC(0) = S: RETURN
3600 PRINT : PRINT "OLD SEX: ";SEX$(0)
3610 INPUT "NEW SEX: ";X$: IF X$ < >"M" AND X$ < >"F" THEN PRINT : PRINT "INVALID SEX": GOTO 3600
3620 UP = 1:SEX$(0) = X$: RETURN
3800 UP = 1: HOME : VTAB 8: PRINT "SELECT ONE:": PRINT : PRINT S$;"1. GOLD IN HAND",GOLD(0): PRINT S$;"2. GOLD IN BANK",BANK(0):X = 2: GOSUB 600: PRINT : ON S GOTO 3810,3830
3810 INPUT "HOW MUCH GOLD IN HAND:";X: IF X <0 OR X >50000 OR X < > INT(X) THEN PRINT : PRINT "INVALID AMOUNT.": GOTO 3810
3820 GOLD(0) = X: RETURN
3830 INPUT "HOW MUCH IN BANK:";X: IF X <0 OR X >50000 OR X < > INT(X) THEN PRINT : PRINT : PRINT "INVALID AMOUNT.": GOTO 3830
3840 BANK(0) = X: RETURN
4000 PRINT : PRINT "OLD ARMOR EXPERTISE:";AE(0): INPUT "NEW ARMOR EXPERTISE:";X: IF X <0 OR X >99 THEN PRINT : PRINT "INVALID EXPERTISE.":X = 0: GOTO 4000
4010 UP = 1:AE(0) = X: RETURN
4200 HOME : VTAB 8: PRINT "SELECT WEAPON TO CHANGE:": PRINT : PRINT " NAME TYPE CMPLX DMG ODDS";: PRINT : FOR I = 1 TO 4
4210 PRINT I;".";WN$(I,0); SPC( 16 - LEN(WN$(I,0)));WT%(I,0); SPC( 6 - LEN( STR$(WO%(I,0))));WO%(I,0);"%";
4220 PRINT SPC( 7 - LEN( STR$(WD%(I,0)) +"D" + STR$(WS%(I,0))));WD%(I,0);"D";WS%(I,0); SPC( 5 - LEN( STR$(2 *AG(0) +WA%(WT%(I,0),0) +WO%(I,0))));2 *AG(0) +WA%(WT%(I,0),0) +WO%(I,0);"%"
4230 NEXT
4240 PRINT "-----------------": PRINT "5. RETURN TO MENU":X = 5: GOSUB 600
4250 W = S: PRINT : IF S = 5 THEN RETURN
4260 PRINT " SELECT FIELD TO CHANGE:": PRINT : PRINT S$;"1. NAME",WN$(W,0): PRINT S$;"2. TYPE",WT%(W,0): PRINT S$;"3. COMP.",WO%(W,0): PRINT S$;"4. DICE",WD%(W,0): PRINT S$;"5. SIDES",WS%(W,0)
4270 PRINT S$;"6. NEXT WEAPON": PRINT S$;"7. RETURN TO WEAPON MENU":X = 7: GOSUB 600
4280 PRINT : ON S GOTO 4290,4300,4340,4350,4360,4370,4200
4290 UP = 1: INPUT "NEW NAME:";WN$(W,0): GOTO 4260
4300 UP = 1: PRINT "NEW TYPE:"
4310 PRINT : PRINT S$;"1. AXE": PRINT S$;"2. BOW": PRINT S$;"3. CLUB": PRINT S$;"4. SPEAR": PRINT S$;"5. SWORD"
4320 PRINT : INPUT WT%(W,0): GOTO 4260
4330 UP = 1: INPUT "NEW TYPE:";WT%(W,0): GOTO 4260
4340 UP = 1: INPUT "NEW ODDS:";WO%(W,0): GOTO 4260
4350 UP = 1: INPUT "NEW DICE:";WD%(W,0): GOTO 4260
4360 UP = 1: INPUT "NEW SIDES:";WS%(W,0): GOTO 4260
4370 W = W +1: ON W GOTO 4260,4260,4260,4260,4380
4380 RETURN
4400 C1 = C:C = 0:SUB = 1: GOSUB 5000:C = C1: RETURN
4600 REM /// CHANGE ARRAY
4610 NA$(C) = NA$(0):SEX$(C) = SEX$(0):GOLD(C) = GOLD(0):BANK(C) = BANK(0):HD(C) = HD(0):AG(C) = AG(0):CH(C) = CH(0)
4620 FOR I = 1 TO 4:SA%(I,C) = SA%(I,0): NEXT : FOR I = 1 TO 5:WA%(I,C) = WA%(I,0): NEXT
4630 AE(C) = AE(0):AC(C) = AC(0): FOR I = 1 TO 4:WN$(I,C) = WN$(I,0):WT%(I,C) = WT%(I,0):WO%(I,C) = WO%(I,0):WD%(I,C) = WD%(I,0):WS%(I,C) = WS%(I,0): NEXT
4640 DD$(C) = DD$(0)
4650 IF UP = 1 THEN UP(C) = 1:UP = 0
4660 POP : GOTO 510
4800 IF FULL = 0 THEN PRINT : PRINT "THE DIMENSIONED ARRAYS ARE FULL. YOU MAY NOT ADD A CHARACTER TO THIS FILE UNTIL THE PROGRAM IS RERUN.": GOSUB 720: RETURN
4810 FOR I = 1 TO NC: IF NA$(I) < >NA$(0) THEN NEXT
4820 IF NA$(I) = NA$(0) THEN PRINT : PRINT " THAT NAME IS ALREADY BEING USED.": GOSUB 720: RETURN
4830 NC = NC +1:C = NC:ADD = 1:UP(C) = 1: IF NC = FULL THEN FULL = 0
4840 GOTO 4610
5000 REM /// DISPLAY CHARACTER
5010 HOME : PRINT "RECORD #: ";: IF SUB = 1 THEN PRINT C1;
5020 IF SUB = 0 THEN PRINT C;
5030 HTAB 15: PRINT "NAME: ";NA$(C)
5040 PRINT : IF SEX$(C) = "M" THEN PRINT "MALE";
5050 IF SEX$(C) = "F" THEN PRINT "FEMALE";
5060 HTAB 20: PRINT "GOLD:"
5070 PRINT "HARDINESS:";: HTAB 12: PRINT HD(C);: HTAB 21: PRINT "IN HAND: ";GOLD(C)
5080 PRINT "AGILITY:";: HTAB 12: PRINT AG(C);: HTAB 21: PRINT "IN BANK: ";BANK(C)
5090 PRINT "CHARM:";: HTAB 12: PRINT CH(C)
5100 HTAB 20: PRINT "WEAPON ABILITY:"
5110 PRINT "SPELL ABILITY:";: HTAB 21: PRINT "1.AXE:";: HTAB 30: PRINT WA%(1,C)
5120 PRINT " BLAST:";: HTAB 12: PRINT SA%(1,C);: HTAB 21: PRINT "2.BOW:";: HTAB 30: PRINT WA%(2,C)
5130 PRINT " HEAL:";: HTAB 12: PRINT SA%(2,C);: HTAB 21: PRINT "3.CLUB:";: HTAB 30: PRINT WA%(3,C)
5140 PRINT " SPEED:";: HTAB 12: PRINT SA%(3,C);: HTAB 21: PRINT "4.SPEAR:";: HTAB 30: PRINT WA%(4,C)
5150 PRINT " POWER:";: HTAB 12: PRINT SA%(4,C);: HTAB 21: PRINT "5.SWORD:";: HTAB 30: PRINT WA%(5,C)
5160 A$ = "NONE"
5170 IF AC(C) = 1 THEN A$ = "SHIELD ONLY": GOTO 5220
5180 IF AC(C) >1 THEN A$ = "LEATHER ARMOR"
5190 IF AC(C) >3 THEN A$ = "CHAIN ARMOR"
5200 IF AC(C) >5 THEN A$ = "PLATE ARMOR"
5210 IF INT(AC(C)/2) < >AC(C)/2 THEN A$ = A$ +" & SHIELD"
5220 PRINT : PRINT "ARMOR: ";A$
5230 PRINT " EXPERTISE: ";AE(C);"%"
5240 PRINT : PRINT "WEAPON INFORMATION:"
5250 PRINT " NAME TYPE CMPLX DMG ODDS";
5260 FOR I = 1 TO 4
5270 PRINT WN$(I,C); SPC( 18 - LEN(WN$(I,C)));WT%(I,C); SPC( 6 - LEN( STR$(WO%(I,C))));WO%(I,C);"%";
5280 PRINT SPC( 7 - LEN( STR$(WD%(I,C)) +"D" + STR$(WS%(I,C))));WD%(I,C);"D";WS%(I,C); SPC( 5 - LEN( STR$(2 *AG(C) +WA%(WT%(I,C),C) +WO%(I,C))));2 *AG(C) +WA%(WT%(I,C),C) +WO%(I,C);"%"
5290 NEXT : IF SUB = 2 THEN SUB = 0: RETURN
5300 GOSUB 720
5310 IF AU = 1 AND C = NC THEN AU = 0:C = 0
5320 IF AU = 1 THEN 1300
5330 IF SUB = 1 THEN SUB = 0: RETURN
5340 GOTO 510
6000 REM /// FILE MAINTENANCE
6010 HOME : VTAB 8: PRINT " SELECT ACTION:": PRINT
6020 PRINT S$;"1. LIST FILE": PRINT S$;"2. SHORT LIST": PRINT S$;"3. CONDENSE FILE": PRINT S$;"4. INIT FILE": PRINT S$;"5. LIST/DELETE CHARACTERS"
6030 PRINT S$;"6. RETURN TO MAIN MENU":X = 6: GOSUB 600
6040 ON S GOTO 6100,6800,6200,6400,6600,510
6100 REM ///LIST FILE
6110 AU = 1:C = 0: GOTO 1300
6200 REM /// CONDENSE FILE
6210 FOR I = 1 TO NC
6220 IF NA$(I) < >"" THEN 6300
6230 FOR J = I TO NC -1:NA$(J) = NA$(J +1):SEX$(J) = SEX$(J +1):GOLD(J) = GOLD(J +1):BANK(J) = BANK(J +1):HD(J) = HD(J +1):AG(J) = AG(J +1):CH(J) = CH(J +1)
6240 FOR K = 1 TO 4:SA%(K,J) = SA%(K,J +1): NEXT
6250 FOR K = 1 TO 5:WA%(K,J) = WA%(K,J +1): NEXT
6260 AC(J) = AC(J +1):AE(J) = AE(J +1)
6270 FOR K = 1 TO 4:WN$(K,J) = WN$(K,J +1):WT%(K,J) = WT%(K,J +1):WO%(K,J) = WO%(K,J +1):WD%(K,J) = WD%(K,J +1):WS%(K,J) = WS%(K,J +1): NEXT
6280 UP(J) = 1: NEXT J
6290 NC = NC -1:ADD = 1
6300 NEXT I: PRINT : PRINT : PRINT SPC( 16)"DONE": FOR I = 1 TO 500: NEXT I: GOTO 6000
6400 REM /// INIT FILE
6410 HOME : VTAB 6: HTAB 16: INVERSE : PRINT "WARNING": NORMAL
6420 FOR I = 1 TO 3: PRINT CHR$(7);: NEXT
6430 PRINT : PRINT : PRINT " THIS SUBROUTINE WILL DELETE EVERY CHARACTER ON THIS DISK!!!"
6440 PRINT : PRINT : PRINT " DO YOU WANT TO DELETE ALL THE": INPUT " CHARACTERS ON THIS DISK? ";A$
6450 IF A$ = "Y" THEN PRINT : PRINT : HTAB 13: INPUT "ARE YOU SURE? ";A$
6460 IF A$ < >"Y" THEN 6000
6470 PRINT D$"CLOSE": PRINT D$;"DELETE CHARACTERS"
6480 NC = 1: PRINT D$;"OPEN CHARACTERS,L150": PRINT D$;"WRITE CHARACTERS,R0": PRINT NC
6490 PRINT D$;"WRITE CHARACTERS,R1": PRINT : PRINT D$:NC = 0: GOTO 410
6600 REM /// CHAR LIST/DELETE
6610 HOME : FOR I = 1 TO NC
6620 PRINT : PRINT "RECORD #";I;": ";NA$(I)
6630 PRINT " KEEP THIS RECORD?";: GET A$: PRINT A$: IF A$ = "N" THEN NA$(I) = "":UP(I) = 1
6640 NEXT
6650 GOTO 6000
6800 REM /// SHORT LIST
6810 FOR I = 1 TO NC: IF DD$(I) < >"" THEN S$ = ""
6820 NEXT
6830 HOME : VTAB 8: PRINT "SHORT LIST:": PRINT : PRINT S$;"REC # NAME";: IF S$ = "" THEN HTAB 20: PRINT "OLD NAME";
6840 PRINT : PRINT : FOR I = 1 TO NC: PRINT S$;" ";I;".";: HTAB 8 + LEN(S$): PRINT NA$(I);: IF DD$(I) < >"" THEN HTAB 21: PRINT "(?)";DD$(I);
6850 PRINT : NEXT
6860 S$ = " ": GOSUB 720: GOTO 6000
7000 REM /// MOVE CHARACTER
7010 IF C = 0 THEN SUB = 1: GOSUB 1000
7020 HOME : PRINT "THIS ROUTINE WILL MOVE AN ADVENTURER FROM ONE DISKETTE/FILE TO ANOTHER. THE CHARACTER MUST BE LOADED WHEN THIS FUNCTION IS EXECUTED."
7030 PRINT : PRINT "THE CHARACTER NOW LOADED IS:": PRINT : HTAB (40 - LEN(NA$(C)))/2: PRINT NA$(C)
7040 PRINT : PRINT "IF THE CHARACTER IS ALREADY LOADED, INSERT THE DISK IT IS TO BE TRANSFERRED TO, AND PRESS 'C'."
7050 PRINT : PRINT "HIT ANY OTHER KEY TO RETURN TO THE MAIN MENU.": PRINT
7060 GET A$: PRINT : IF A$ < >"C" THEN 510
7062 INPUT "PREFIX OF TRANSFER DISK: ";TX$: IF TX$ = "" THEN 510
7064 ONERR GOTO 11000
7066 PRINT D$"PREFIX"TX$
7067 ONERR GOTO 7080
7070 PRINT D$"CLOSE": PRINT D$"OPEN CHARACTERS,L150": PRINT D$"READ CHARACTERS,R0": INPUT C2: PRINT D$: GOTO 7080
7080 POKE 216,0: PRINT : PRINT " SELECT ACTION:": PRINT S$;"1. ADD CHARACTER AS NEW": PRINT S$;"2. REPLACE EXISTING CHARACTER": PRINT S$;"3. LIST CHARACTERS IN THIS FILE": PRINT S$;"4. RETURN TO MAIN MENU":X = 4: GOSUB 600
7090 ON S GOTO 7200,7300,7800,7600
7200 REM /// ADD NEW CHARACTER
7210 I = C2 +1: GOSUB 7700
7220 PRINT D$"WRITE CHARACTERS,R0": PRINT I: GOTO 7530
7300 REM /// REPLACE CHARACTER
7305 IF C2 = 0 AND S < >1 THEN PRINT : PRINT "***NEW FILE***": GOTO 7080
7310 PRINT : PRINT " SELECT METHOD:": PRINT S$;"1. REPLACE BY NAME": PRINT S$;"2. REPLACE BY RECORD #": PRINT S$;"3. RETURN TO FIRST MENU":X = 3: GOSUB 600
7320 ON S GOTO 7400,7500,7080
7400 PRINT : HTAB 10: INPUT "NAME:";N1$
7410 FOR I = 1 TO C2: PRINT D$"READ CHARACTERS,R";I: INPUT N2$: IF N2$ < >N1$ THEN NEXT : PRINT D$: PRINT : PRINT "I DON'T FIND THAT NAME.": GOTO 7080
7420 PRINT D$: GOSUB 7700: GOTO 7530
7500 REM /// REPLACE BY REC#
7510 PRINT D$: PRINT : HTAB 10: INPUT "RECORD #:";I: IF I < > INT(I) OR I >C2 OR I <1 THEN PRINT D$: PRINT : PRINT "THE HIGHEST RECORD IN THIS FILE IS ";C2: GOTO 7080
7520 GOSUB 7700
7530 PRINT D$"WRITE CHARACTERS,R"I:I = C: GOSUB 9140
7540 PRINT : HTAB 18: PRINT "DONE.": PRINT : GOSUB 720
7600 REM /// RETURN
7610 PRINT D$"CLOSE": HOME : VTAB 5: PRINT " INSERT ORIGINAL DISKETTE AND PRESS": HTAB 16: PRINT "ANY KEY": GET A$: PRINT
7615 PRINT D$"PREFIX"PX$
7620 PRINT D$"OPEN CHARACTERS,L150": GOTO 510
7700 IF C2 = 0 THEN PRINT : PRINT "***NEW FILE***": RETURN
7705 FOR J = 1 TO C2: PRINT D$;"READ CHARACTERS,R";J: INPUT N$
7710 IF NA$(C) = N$ AND I < >J THEN PRINT D$: PRINT CHR$(7): PRINT "THE CHARACTER NAME ";NA$(C): PRINT "ALREADY EXISTS IN THIS FILE IN RECORD ";J: POP : GOTO 7080
7720 NEXT : RETURN
7800 IF C2 = 0 THEN PRINT : PRINT "***NEW FILE***": GOTO 7080
7810 PRINT : FOR J = 1 TO C2: PRINT D$;"READ CHARACTERS,R";J: INPUT N$: PRINT S$;J;". ";N$: NEXT : PRINT D$: GOTO 7080
8000 REM // GENERATE NEW RECORD
8010 PRINT : INPUT "NAME OF NEW CHARACTER: ";NA$(0)
8020 HD(0) = 0:AG(0) = 0:CH(0) = 0: FOR I = 1 TO 5:WA%(I,0) = 0: NEXT
8030 FOR I = 1 TO 4:SA%(I,0) = 0: NEXT :GOLD(0) = 0:BANK(0) = 0: FOR I = 1 TO 4:WN$(I,0) = "NONE":WT%(I,0) = 0:WD%(I,0) = 0:WO%(I,0) = 0:WS%(I,0) = 0: NEXT
8040 AE = 0:AC = 0
8050 ADD = 1:NC = NC +1:C = NC:UP(C) = 1: IF NC = FULL THEN FULL = 0
8060 NA$(C) = NA$(0): GOTO 2000
9000 REM /// QUIT ROUTINE
9010 PRINT D$;"CLOSE"
9020 FOR I = 1 TO NC: IF UP(I) = 1 THEN GOSUB 9110
9030 NEXT
9040 IF ADD THEN PRINT D$"OPEN CHARACTERS,L150": PRINT D$"WRITE CHARACTERS,R0": PRINT NC: PRINT D$:
9050 PRINT D$;"CLOSE": VTAB 20: HTAB 8: PRINT "*** END OF PROGRAM ***": PRINT : PRINT D$"-EAMON.MASTER"
9100 REM /// WRITE RECORD
9110 PRINT D$;"OPEN CHARACTERS,L150"
9120 IF DD$(I) < >"" THEN NA$(I) = ""
9130 PRINT D$"WRITE CHARACTERS,R";I
9140 PRINT NA$(I): PRINT HD(I): PRINT AG(I): PRINT CH(I): FOR J = 1 TO 4: PRINT SA%(J,I): NEXT : FOR J = 1 TO 5: PRINT WA%(J,I): NEXT
9150 PRINT AE(I): PRINT SEX$(I): PRINT GOLD(I): PRINT BANK(I): PRINT AC(I)
9160 FOR J = 1 TO 4: PRINT WN$(J,I): PRINT WT%(J,I): PRINT WO%(J,I): PRINT WD%(J,I): PRINT WS%(J,I): NEXT : PRINT D$
9165 PRINT D$"CLOSE"
9170 RETURN
10000 REM ///ONERR ROUTINE
10010 CALL 768
10020 IF NC = 1 AND PEEK(222) = 5 THEN NC = 0: GOTO 410
10030 PRINT D$;"CLOSE"
10040 PRINT D$;"OPEN CHARACTERS,L150"
10050 GOTO 410
11000 IF PEEK(222) = 6 THEN PRINT : PRINT : PRINT CHR$(7); CHR$(7); CHR$(7);"PATH NOT FOUND": PRINT : PRINT : POKE 216,0: FOR I = 1 TO 1000: NEXT : GOTO 7000
Text found in disk135.dsk/EAMON.MASTER.bas:
1 REM EAMON.MASTER(PRODOS EAMON STARTUP MENU)BY TOM ZUCHOWSKI
2 REM 9/19/90
6 REM EAMON ADVENTURER'S GUILD7625 HAWKHAVEN DR.CLEMMONS, NC 27012
10 D$ = CHR$(4)
20 PRINT CHR$(26);"1": REM TURN OFF VIDEX VIDEOTERM
25 PRINT CHR$(26); CHR$(17): REM TURN OFF IIE 80-COL.
30 PRINT D$"PR#0"
40 HOME : PRINT "EAMON ADVENTURER'S GUILD": PRINT "7625 HAWKHAVEN DR.": PRINT "CLEMMONS, NC 27012": PRINT "(919)766-7490"
50 PRINT : PRINT : PRINT "LAST UPDATE: 9/19/90"
60 PRINT : PRINT : PRINT "TO MAKE THIS DISK BOOTABLE IN THE 5.25 FORMAT, MAKE A COPY AND DELETE THE FILE 'PLAYER.MANUAL'. ADD PRODOS AND BASIC.SYSTEM , AND A 'STARTUP' PROGRAM THAT CONTAINS THIS COMMAND:"
70 PRINT : PRINT " 10 PRINT CHR$(4)" CHR$(34)"-EAMON.MASTER" CHR$(34)
80 VTAB 19: PRINT "THIS PROGRAM REQUIRES UPPER-CASE INPUT. DEPRESS YOUR CAPS-LOCK AND PRESS 'C' TO CONTINUE."
90 GET A$: PRINT A$: IF A$ < >"C" THEN 80
100 REM MAIN MENU
110 HOME :: HTAB 15: INVERSE : PRINT ": :": HTAB 15: PRINT " EAMON MASTER ": HTAB 15: PRINT ": :": NORMAL
120 VTAB 7: HTAB 10: PRINT "1) ENTER THE MAIN HALL": PRINT
130 HTAB 10: PRINT "2) RESURRECT A CHARACTER": PRINT
140 HTAB 10: PRINT "3) LIST CHARACTERS": PRINT
150 HTAB 10: PRINT "4) EDIT CHARACTER FILE": PRINT
160 HTAB 10: PRINT "5) PLAYER MANUAL": PRINT
165 HTAB 10: PRINT "6) EXIT EAMON (BYE)": PRINT
170 HTAB 10: PRINT "7) QUIT TO BASIC": PRINT
180 A$ = "":A = 0: VTAB 22: PRINT "ENTER THE NUMBER OF YOUR SELECTION: ";: POKE -16368,0: GET A$: PRINT A$
190 A = VAL(A$): IF A <1 OR A >7 THEN 100
200 ON A GOTO 1000,2000,3000,4000,5000,6000,7000
1000 REM ENTER THE MAIN HALL
1010 PRINT D$"-FRONT.DESK"
2000 REM RESURRECT CHARACTER
2010 HOME : VTAB 5
2020 PRINT D$"OPEN CHARACTERS,L150"
2030 PRINT : PRINT "NAME OF CHARACTER TO BE RESURRECTED:": PRINT : INPUT NA$
2040 PRINT D$"READ CHARACTERS,R0": INPUT NC
2050 FOR R = 1 TO NC: PRINT D$"READ CHARACTERS,R"R: INPUT N$: INPUT ME$
2055 IF N$ = NA$ THEN R = 999: NEXT : GOTO 2200
2060 IF N$ < >"" THEN NEXT : GOTO 2210
2070 IF ME$ < > MID$ (NA$,2) THEN NEXT : GOTO 2210
2080 RR = R:R = 999: NEXT
2090 PRINT D$"WRITE CHARACTERS,R"RR: PRINT NA$: PRINT D$"CLOSE"
2100 PRINT : PRINT NA$" HAS BEEN RESURRECTED.": GOTO 2300
2200 PRINT : PRINT NA$" ISN'T DEAD.": GOTO 2300
2210 PRINT : PRINT NA$" DOESN'T EXIST.": GOTO 2300
2300 PRINT D$"CLOSE"
2310 GOTO 10000
3000 REM LIST CHARACTERS
3005 HOME : VTAB 5
3010 PRINT D$"OPEN CHARACTERS,L150"
3020 PRINT D$"READ CHARACTERS,R0": INPUT NC: FOR R = 1 TO NC: PRINT D$"READ CHARACTERS,R"R
3030 INPUT N$: IF N$ < >"" THEN 3050
3040 INPUT N2$
3050 PRINT D$: PRINT "#";R;": ";N$;: IF N$ = "" THEN PRINT "-"N2$" (DEAD)";
3060 PRINT D$: PRINT
3070 NEXT : PRINT D$"CLOSE"
3080 GOTO 10000
4000 REM EDIT CHAR. FILE
4010 PRINT D$"RUN CHAR.FILE.MAINT"
5000 REM PLAYER MANUAL
5002 ONERR GOTO 5006
5004 PRINT D$"VERIFY PLAYER.MANUAL": POKE 216,0: PRINT D$: GOTO 5010
5006 HOME : PRINT CHR$(7): VTAB 10: HTAB 7: PRINT "PLAYER.MANUAL NOT FOUND.": POKE 216,0: PRINT D$: GOTO 10000
5010 HOME
5020 PRINT "THE PLAYER'S MANUAL IS CONTAINED IN A TEXT FILE ON THIS DISK THAT IS NAMED 'PLAYER.MANUAL'."
5030 PRINT : PRINT "THIS IS A SIMPLE ASCII-TEXT FILE AND IT IS RECOMMENDED THAT YOU USE A TEXT- EDITING PROGRAM."
5040 PRINT : PRINT "IF YOU DO NOT HAVE A WORD PROCESSOR OR TERMINAL PROGRAM THAT CAN ACCESS THIS FILE, THIS ROUTINE CAN DUMP THE MANUAL TO SCREEN OR PRINTER."
5050 PRINT : PRINT "WARNING: THE MANUAL IS 10 PRINTED PAGES, AND THIS PRINT ROUTINE IS IN BASIC AND IS *VERY* SLOW!"
5060 PRINT : PRINT "DO YOU WISH TO USE THIS PROGRAM TO DUMP THE FILE TO YOUR PRINTER?";: POKE -16368,0: GET A$: PRINT A$:
5062 IF A$ = "Y" THEN CP = 80: GOTO 5080
5065 PRINT : PRINT "DO YOU WISH TO USE THIS PROGRAM TO DUMP THE FILE TO YOUR SCREEN?";: POKE -16368,0: GET A$: PRINT A$:
5070 IF A$ < >"Y" THEN 10000
5075 HOME :CP = 40: GOTO 5120
5080 PRINT : PRINT "PRINTER SLOT #";: POKE -16368,0: GET P$: PRINT P$:P = VAL(P$):P$ = "": IF P <1 OR P >7 THEN PRINT "ABORTED.": PRINT : PRINT : PRINT : GOTO 10000
5090 PRINT : PRINT "READY YOUR PRINTER AND TYPE 'P' TO PRINT MANUAL"
5100 POKE -16368,0: GET A$: PRINT A$:: IF A$ < >"P" THEN PRINT "ABORTED": PRINT : PRINT : PRINT : GOTO 10000
5110 PRINT D$"PR#"P
5120 PRINT D$"OPEN PLAYER.MANUAL"
5130 ONERR GOTO 5400
5140 PRINT D$"READ PLAYER.MANUAL"
5150 GET A$
5160 IF A$ = CHR$(13) THEN PRINT P$:P$ = "":A$ = "":LP = LP +1: IF LP >60 THEN PRINT CHR$(12):LP = 0
5170 P$ = P$ +A$: IF LEN(P$) " " THEN NEXT
5190 PRINT LEFT$(P$,P -1):LP = LP +1: IF LP >60 THEN PRINT CHR$(12):LP = 0
5200 P$ = MID$ (P$,P +1):P = 0: NEXT : GOTO 5150
5400 PRINT D$"CLOSE": PRINT D$"PR#0": GOTO 10000
6000 REM EXIT EAMON AND RUN NEXT APPLICATION
6010 PRINT D$"BYE"
7000 REM EXIT TO BASIC
7010 END
10000 VTAB 22: HTAB 7: INVERSE : PRINT "(HIT ANY KEY TO CONTINUE)": NORMAL : POKE -16368,0: GET A$: PRINT A$:A$ = "": GOTO 100
Text found in disk135.dsk/FRONT.DESK.bas:
10 REM THE WONDERFUL WORLD OF
20 REM EAMON
30 REM
40 REM A COMPUTERIZED FANTASY
50 REM ROLE-PLAYING SYSTEM
60 REM
70 REM RULES AND CORE PROGRAMS
80 REM BY DONALD BROWN
90 REM 407 PEERY PARKWAY
100 REM GOLDEN, CO 80401
110 REM
120 REM DRAGON PICTURE SHOWN
130 REM DURING PROGRAM BY
140 REM R.L. PHILLIPS & FRIENDS
150 REM OF ANN ARBOR, MICH.
160 REM THE BEAUTY IS GREATLY
170 REM ENJOYED.
180 REM
190 REM ///BOOTUP PROGRAM FOR
200 REM ///EAMON UNIVERSE.
210 REM ///GETS NAME OF PLAYER
220 REM ///AND EITHER SENDS TO
230 REM ///MAIN HALL (IF OLD
240 REM ///CHARACTER) OR TO NEW
250 REM ///CHARACTERS (IF NEW).
260 REM
280 DK$ = CHR$(4): HOME : IF PEEK(49152) = 155 THEN 290
282 PRINT DK$;"BLOAD EAMON.PIC,A$2000": POKE -16304,0: POKE -16297,0: POKE -16302,0
290 PRINT DK$;"OPEN CHARACTERS,L150": PRINT DK$;"READ CHARACTERS,R0": INPUT NC: PRINT DK$
292 PRINT DK$"OPEN SNAPPY,L64": PRINT DK$"READ SNAPPY,R0": INPUT NS: PRINT DK$
300 VTAB 5: PRINT " YOU ARE IN THE OUTER CHAMBER OF THE": PRINT : PRINT "HALL OF THE GUILD OF FREE ADVENTURERS.": PRINT : PRINT "MANY MEN AND WOMEN ARE GUZZLING BEER"
310 PRINT : PRINT "AND THERE IS LOUD SINGING AND LAUGHTER.": PRINT : PRINT : PRINT " ON THE NORTH SIDE OF THE CHAMBER IS"
320 PRINT : PRINT "A CUBBYHOLE WITH A DESK. OVER THE DESK": PRINT : PRINT "IS A SIGN WHICH SAYS 'REGISTER HERE": PRINT : PRINT "OR ELSE!'": PRINT
330 PRINT : PRINT "DO YOU GO OVER TO THE DESK OR JOIN THE": PRINT : PRINT " MEN DRINKING THE BEER?": PRINT : PRINT " (HIT 'D' FOR DESK OR 'M' FOR MEN) ";
340 POKE -16368,0: FOR X = 1 TO 1000: IF PEEK( -16384) <128 THEN NEXT X
350 POKE -16368,0: TEXT
360 GET A$: IF A$ = "D" THEN 390
370 IF A$ < >"M" THEN 360
380 PRINT A$
382 PRINT : PRINT : PRINT " AS YOU GO OVER TO THE MEN, YOU FEEL": PRINT : PRINT "A SWORD BEING THRUST THROUGH YOUR BACK": PRINT : PRINT "AND YOU HEAR SOMEONE SAY, 'YOU REALLY": PRINT : PRINT "MUST LEARN TO FOLLOW DIRECTIONS!'"
384 PRINT DK$"CLOSE": PRINT DK$"-EAMON.MASTER"
390 PRINT A$: PRINT : PRINT : PRINT " YOU ARE GREETED THERE BY A BURLY": PRINT : PRINT "IRISHMAN WHO LOOKS AT YOU WITH A SCOWL": PRINT : PRINT "AND ASKS YOU, 'WHAT'S YOUR NAME?'": PRINT : PRINT
400 INPUT "YOU GIVE HIM YOUR NAME (TYPE IT IN NOW) ";NAME$
410 PRINT : IF NAME$ = "" OR LEN(NAME$) <2 OR LEFT$(NAME$,1) <"A" OR LEFT$(NAME$,1) >"Z" THEN GOSUB 550: GOTO 400
420 IF LEN(NAME$) >20 THEN PRINT " HE SCOWLS AT YOU AND SAYS, 'YER": PRINT : PRINT "NAME'S TOO LONG FER ME BOOK. I CANNA": PRINT : PRINT "USE MORE THAN TWENTY LETTERS.": PRINT : GOTO 400
430 X = RND( - PEEK(78) - PEEK(79))
440 RX = INT( RND(1) *NS) +1
442 PRINT DK$"READ SNAPPY,R"RX: INPUT CM$
444 L = LEN(CM$): IF L <26 THEN C1$ = CM$:C2$ = ""
446 IF L >25 THEN C1$ = LEFT$(CM$,24):C2$ = MID$ (CM$,25)
450 PRINT " HE STARTS LOOKING THROUGH HIS BOOK,": PRINT : PRINT "MUTTERING ABOUT "C1$: PRINT C2$".": PRINT : PRINT
460 FOR R = 1 TO NC: PRINT DK$;"READ CHARACTERS,R";R: INPUT A$: INPUT A1$: IF A$ = NAME$ THEN 520
465 IF A$ = "" THEN IF A1$ = MID$ (NA$,2) THEN A1 = R
470 NEXT R: PRINT DK$: PRINT " HE EVENTUALLY LOOKS AT YOU AND SAYS,": PRINT : PRINT "'YER NAME'S NA IN HERE. HAVE YE GIVEN": PRINT : PRINT "IT TO ME ARIGHT?'": PRINT : PRINT "HOW DO YOU ANSWER (HIT 'Y' OR 'N') ";
480 GET A$: IF A$ = "N" THEN PRINT A$: PRINT : GOSUB 550: GOTO 400
490 IF A$ < >"Y" THEN 480
495 IF A1 THEN PRINT : PRINT : PRINT : PRINT " HE LOOKS AT YOU STRANGELY, AND SAYS,": PRINT : PRINT "BUT..."NA$" IS DEAD!": FOR I = 1 TO 2000: NEXT : PRINT DK$"-EAMON.MASTER"
500 PRINT A$: PRINT : PRINT " HE HITS HIS FOREHEAD AND SAYS, 'AH,": PRINT : PRINT "YE MUST BE NEW HERE! WELL, WAIT JUST": PRINT : PRINT "A MINUTE AND I'LL BRING SOMEONE OUT TO": PRINT : PRINT "TAKE CARE OF YE.'": PRINT
510 GOSUB 540: PRINT DK$"RUN NEW.CHARACTER"
520 PRINT DK$: PRINT : PRINT " HE LOOKS UP AND SAYS, 'AH, HERE YE": PRINT : PRINT "BE! WELL, GO AND HAVE FUN IN THE HALL!'": PRINT
530 GOSUB 540: PRINT DK$"RUN MAIN.HALL
540 PRINT DK$;"OPEN THE.ADVENTURER": PRINT DK$;"WRITE THE.ADVENTURER": PRINT NAME$: PRINT R: PRINT DK$;"CLOSE": RETURN
550 REM ///NO NAME ROUTINE
560 CNT = CNT +1: IF CNT >1 THEN 590
570 PRINT " HE PULLS OUT A SWORD AND BEGINS TO": PRINT "SHARPEN IT, SAYING 'YE'D BEST BE GIVIN'": PRINT "ME YER NAME LADDIE, IF YE KNOW WOTS": PRINT "GOOD FER YE!!!"
580 RETURN
590 IF CNT = 2 THEN PRINT "I'VE 'BOUT HAD ME FILL O' YER SICK": PRINT "SENSA 'UMOR!!": PRINT "NOW GIMME YER NAME!!": RETURN
600 IF CNT = 3 THEN PRINT "THE MAN CUTS ONE OF YOUR FINGERS OFF!!": PRINT "HE THEN EATS IT!!!!": PRINT "THEN HE SAYS 'ARE YE READY T' TALK NOW?": RETURN
610 IF CNT <13 THEN PRINT "THE MAN CUTS OFF ANOTHER FINGER!!!": PRINT "HE EATS THIS ONE TOO!!": RETURN
620 PRINT "THE MAN STARTS SLOWLY, 'WELL YE BE ": PRINT "OUTTA FINGERS!'": PRINT "THE MAN THEN SPINS AROUND AND RUNS YOU": PRINT "THROUGH WITH A SPEED YOU HAVE NEVER": PRINT "SEEN BEFORE! (AND NEVER WILL AGAIN.)": PRINT DK$"-EAMON.MASTER"
Text found in disk135.dsk/MAIN.HALL.bas:
1 REM THE WONDERFUL WORLD OF EAMON MAIN HALL(BUY SPELLS AND EQUIPMENT AND GO ON ADVENTURES)ORIGINATED BY DONALD BROWN
5 REM PRODOS CONVERSION 1/11/90 TJZ
6 REM MH10
7 REM LAST UPDATE 1/24/90
10 REM EAMON ADVENTURER'S GUILD7625 HAWKHAVEN DR.CLEMMONS, NC 27012
12 DK$ = CHR$(4)
14 PRINT DK$"PREFIX": INPUT PX$
20 ONERR GOTO 7000
25 PRINT DK$"VERIFY THE.ADVENTURER"
30 PRINT DK$;"OPEN THE.ADVENTURER": PRINT DK$;"READ THE.ADVENTURER": INPUT NAME$: INPUT REC: PRINT DK$;"CLOSE"
40 ONERR GOTO 100
50 PRINT DK$;"OPEN CHARACTERS,L150": PRINT DK$;"READ CHARACTERS,R";REC: INPUT NAME$: INPUT HD,AG,CH: FOR X = 1 TO 4: INPUT SA%(X): NEXT : FOR X = 1 TO 5: INPUT WA%(X): NEXT : INPUT AE
60 INPUT SEX$
70 INPUT GOLD,BANK: INPUT AC: FOR W = 1 TO 4: INPUT WNAME$(W),WTYPE%(W),WODDS%(W),WDICE%(W),WSIDES%(W): NEXT W: PRINT DK$;"CLOSE"
80 DEF FN P(X) = INT(X *RTIO +.5)
82 TT = 255: DIM B$(TT)
100 POKE 216,0: PRINT : PRINT "AS YOU WANDER ABOUT THE HALL, YOU": PRINT "REALIZE YOU CAN DO ONE OF SIX THINGS--": PRINT " 1. GO ON AN ADVENTURE.": PRINT " 2. VISIT THE WEAPON SHOP FOR WEAPONS AND/OR ARMOUR."
110 PRINT " 3. HIRE A WIZARD TO TEACH YOU SOME SPELLS.": PRINT " 4. FIND THE BANKER TO DEPOSIT OR": PRINT " WITHDRAW SOME GOLD.": PRINT " 5. EXAMINE YOUR ABILITIES.": PRINT " 6. TEMPORARILY LEAVE THE UNIVERSE."
120 PRINT : PRINT "(HIT THE KEY FOR YOUR CHOICE, 1-6)";
130 GET A$:CMD = VAL(A$): IF CMD <1 OR CMD >6 THEN 130
140 PRINT CMD: PRINT : ON CMD GOTO 1000,2000,3000,4000,5000,6000
200 PRINT NAME$: PRINT HD: PRINT AG: PRINT CH: FOR X = 1 TO 4: PRINT SA%(X): NEXT : FOR X = 1 TO 5: PRINT WA%(X): NEXT : PRINT AE: PRINT SEX$
210 PRINT GOLD: PRINT BANK: PRINT AC: FOR W = 1 TO 4: PRINT WNAME$(W): PRINT WTYPE%(W): PRINT WOODS%(W): PRINT WDICE%(W): PRINT WSIDES%(W): NEXT W
220 RETURN
1000 REM GO ON ADVENTURE
1010 HOME : PRINT DK$;"OPEN CHARACTERS,L150": PRINT DK$;"WRITE CHARACTERS,R";REC: PRINT : PRINT DK$;"CLOSE"
1020 CX$ = LEFT$(PX$, LEN(PX$) -1)
1030 HOME : PRINT "IF NECESSARY, INSERT ADVENTURE DISK NOW (KEEP MASTER DISK FOR BEGINNERS CAVE) THEN HIT 'C' TO CONTINUE";: POKE -16368,0: GET A$: PRINT : IF A$ < >"C" THEN PRINT CHR$(7): GOTO 1030
1040 PRINT : PRINT "CURRENT PREFIX: ";CX$"/"
1060 PRINT : PRINT "ENTER PREFIX FOR ADVENTURE:": PRINT " (TYPE '?' FOR LIST OF DIRECTORIES)": PRINT " (TYPE 'EXIT' TO RETURN TO MENU)": PRINT : INPUT "PREFIX: ";AX$
1070 IF AX$ = "EXIT" THEN 1800
1080 IF AX$ < >"?" THEN 1200
1100 PRINT : PRINT "AVAILABLE DIRECTORIES:":X = 1
1105 PRINT : PRINT DK$"OPEN"CX$",TDIR": PRINT DK$"READ"CX$: INPUT A$: INPUT A$: INPUT A$
1110 INPUT B$: IF B$ = "" THEN 1125
1120 IF MID$ (B$,18,3) < >"DIR" THEN 1110
1121 B$(X) = "/" + MID$ (B$,2,16)
1122 IF RIGHT$(B$(X),1) = " " THEN B$(X) = LEFT$(B$(X), LEN(B$(X)) -1): GOTO 1122
1123 PRINT B$(X):X = X +1: GOTO 1110
1125 PRINT DK$"CLOSE"
1130 PRINT :DX$ = "":A1 = 1:B = 1: PRINT : PRINT " STEP THROUGH DIRECTORIES KEY TO SELECT DIRECTORY KEY TO EXIT TO PREVIOUS MENU TYPE DIRECTORY NAME: ( <-- TO ERASE)": PRINT : PRINT
1131 B$(X) = "": IF X >13 THEN 1160
1132 VT = PEEK(37):B1 = B
1133 VTAB VT -X +B1 -6: PRINT B$(B1 +1)
1134 VTAB VT -X +B -7: INVERSE : PRINT B$(B): NORMAL : VTAB VT: HTAB A1
1135 VTAB VT -X +B1 -8: HTAB 1: PRINT B$(B1 -1 +( NOT B1)): IF B2 THEN B2 = 0:B1 = B: VTAB VT -X +B -7
1136 INVERSE : PRINT B$(B): NORMAL : VTAB VT: HTAB A1
1138 POKE -16368,0: GET A$:A = ASC(A$): IF (A = 21 OR A = 10) AND DX$ < >"" THEN 1134
1139 IF (A = 8 OR A = 11) AND DX$ < >"" THEN 1133
1140 IF A = 21 OR A = 10 THEN RV = 0:B = B +1:B1 = B1 +1: IF B = X THEN B2 = 1:B = 1
1141 IF A = 8 OR A = 11 THEN RV = 1:B = B -1:B1 = B1 -1: IF B = 0 THEN B2 = 1:B = X -1
1142 IF A = 21 OR A = 10 THEN ON (A1 >1) +1 GOTO 1135,1138
1143 IF A = 8 OR A = 11 THEN ON (A1 >1) +1 GOTO 1133,1138
1144 IF A = 27 THEN 1030
1146 IF A = 13 THEN IF DX$ = "" THEN CX$ = CX$ +B$(B): GOTO 1210
1148 IF A = 13 THEN AX$ = DX$: GOTO 1190
1150 IF A = 8 THEN IF A1 >2 THEN A1 = A1 -1: HTAB A1: PRINT " ";: HTAB A1:DX$ = LEFT$(DX$,A1 -1): GOTO 1134
1152 IF A = 8 THEN A1 = 1: HTAB A1: PRINT " ";: HTAB A1:DX$ = "": GOTO 1134
1153 IF A <46 THEN PRINT CHR$(7);: GOTO 1138
1154 DX$ = DX$ +A$:A1 = A1 +1: PRINT A$;: GOTO 1138
1160 PRINT
1162 VTAB 22: PRINT " ";: HTAB 1: INVERSE : PRINT B$(B): NORMAL : PRINT
1164 POKE -16368,0: GET A$:A = ASC(A$): IF A = 21 OR A = 10 THEN IF DX$ = "" THEN B = B +1
1165 IF A = 8 OR A = 11 THEN IF DX$ = "" THEN B = B -1
1166 IF B = X THEN B = X -1
1167 IF B = 0 THEN B = 1
1168 IF A = 21 OR A = 10 OR A = 8 OR A = 11 THEN ON (A1 >1) +1 GOTO 1162,1164
1170 IF A = 27 THEN 1030
1172 IF A = 13 THEN IF DX$ = "" THEN CX$ = CX$ +B$(B): GOTO 1210
1173 IF A = 13 THEN AX$ = DX$: GOTO 1190
1174 IF A = 8 THEN IF A1 >2 THEN A1 = A1 -1: HTAB A1: PRINT " ";: HTAB A1:DX$ = LEFT$(DX$,A1 -1): GOTO 1164
1175 IF A = 8 THEN A1 = 1: HTAB A1: PRINT " ";: HTAB A1:DX$ = "": GOTO 1162
1176 IF A <46 THEN PRINT CHR$(7);: GOTO 1164
1177 IF DX$ = "" THEN VTAB 22: PRINT " ";: HTAB 1
1178 DX$ = DX$ +A$:A1 = A1 +1: PRINT A$;: GOTO 1164
1190 IF LEFT$(AX$,1) < >"/" THEN AX$ = "/" +AX$
1192 CX$ = CX$ +AX$: PRINT : PRINT "PREFIX:": PRINT " ";CX$: GOTO 1210
1200 IF AX$ = "" THEN AX$ = CX$: PRINT CX$
1202 IF RIGHT$(AX$,1) = "/" THEN AX$ = LEFT$(AX$, LEN(AX$) -1)
1205 CX$ = AX$: IF LEFT$(CX$,1) < >"/" THEN CX$ = "/" +CX$
1210 ONERR GOTO 1217
1215 PRINT DK$"PREFIX"CX$: GOTO 1220
1217 PRINT CHR$(7): HTAB 12: INVERSE : PRINT "PATHNAME ERROR": NORMAL : GOTO 1040
1220 ONERR GOTO 1250
1230 PRINT DK$"VERIFY LEADIN"
1240 POKE 216,0: GOTO 1500
1250 POKE 216,0: PRINT CHR$(7): PRINT " NOT RECOGNIZED AS AN EAMON ADVENTURE SUBDIRECTORY - NO LEADIN PGM": FOR A = 1 TO 2000: NEXT : GOTO 1100
1260 END
1500 PRINT DK$;"OPEN EAMON.NAME": PRINT DK$;"READ EAMON.NAME": INPUT ADNAME$: PRINT DK$;"CLOSE"
1510 HOME : VTAB 5: PRINT "YOU ARE ABOUT TO ADVENTURE IN": PRINT : INVERSE : PRINT ADNAME$: NORMAL : PRINT : PRINT
1520 PRINT DK$"OPEN EAMON.PREFIX": PRINT DK$"WRITE EAMON.PREFIX": PRINT PX$: PRINT DK$"CLOSE"
1530 PRINT DK$;"OPEN FRESH.MEAT": PRINT DK$;"WRITE FRESH.MEAT": PRINT REC: GOSUB 200: PRINT DK$;"CLOSE": PRINT DK$;"RUN LEADIN"
1800 PRINT : PRINT "PREFIX: "PX$: PRINT : PRINT "INSERT MASTER DISK AND TYPE 'C'": GET A$: PRINT A$: IF A$ < >"C" THEN PRINT CHR$(7): GOTO 1800
1810 PRINT DK$"PREFIX"PX$: GOTO 100
2000 PRINT : PRINT "AS YOU ENTER THE WEAPON SHOP, MARCOS": PRINT "CAVIELLI (THE OWNER) COMES FROM OUT OF": PRINT "THE BACK ROOM AND SAYS, 'WELL, AS I"
2010 PRINT "LIVE AND BREATH, IF IT ISN'T MY OLD PAL": PRINT NAME$;"! SO, YOU WANT TO": PRINT "BUY A WEAPON, SELL A WEAPON, OR GET": PRINT "SOME BETTER ARMOUR?": PRINT : PRINT "(HIT THE KEY, B S OR A) ";
2020 C2 = CH + INT(11 * RND(1) -5):C2 = C2 +(C2 = 0):RTIO = 10/C2
2030 GET A$: FOR TR = 1 TO 3: IF A$ < > MID$ ("BSA",TR,1) THEN NEXT : GOTO 2030
2040 PRINT A$: PRINT : ON TR GOTO 2050,2220,2490
2050 IF WN$(4) < >"NONE" THEN PRINT "MARCOS SMILES AT YOU AND SAYS, 'THATSA": PRINT "GOOD, BUT FIRST YOU GOTTA SELL ME A": PRINT "WEAPON. YOU KNOW THE LAW--NO MORE THAN": PRINT "FOUR WEAPONS PER PERSON!'": PRINT : GOTO 2220
2060 PRINT "MARCOS SMILES AT YOU AND SAYS, 'GOOD.": PRINT "I GOTTA THE BEST. YOU WANTA AXE, BOW,": PRINT "MACE, SPEAR, OR SWORD?": PRINT : GOSUB 2650
2070 PRINT : PRINT "MARCOS SAYS, 'WELL, I JUST HAPPEN TO": PRINT "HAVE THREE ";N$;"S IN, OF VARYING": PRINT "QUALITY. I'VE GOT A VERY GOOD ONE FOR": PRINT FN P(2 *BP);" GP, A FAIR ONE FOR "; FN P(BP);" GP,"
2080 PRINT "AND A KINDA SHABBY ONE FOR "; FN P(BP/2): PRINT "WHICH DO YOU WANT?'": PRINT : PRINT "(HIT THE KEY, G F OR P) ";
2090 GET A$: FOR Q = 1 TO 3: IF A$ < > MID$ ("GFP",Q,1) THEN NEXT : GOTO 2090
2100 PRINT A$:P = BP +BP *(Q = 1) -BP/2 *(Q = 3):P = FN P(P)
2110 IF P >GOLD THEN PRINT : PRINT "MARCOS SHAKES A FINGER AT YOU AND SAYS,": PRINT "'YOU SHOULDN'T PLAY TRICKS ON AN OLD": PRINT "FRIEND! COME BACK WHEN YOU GOTTA MORE": PRINT "GOLD OR YOU WANT SOMETHING YOU CAN": PRINT "AFFORD.' HE THEN SHOOS YOU OUT THE": PRINT "DOOR.": PRINT : GOTO 100
2120 FOR W = 1 TO 4: IF WN$(W) = N$ THEN N$ = N$ +"#": GOTO 2120
2130 NEXT W: FOR W = 1 TO 4: IF WN$(W) < >"NONE" THEN NEXT
2140 WN$(W) = N$:WT%(W) = TP:WO%(W) = 10 *(2 -Q):WD%(W) = DICE:WS%(W) = SIDES:GOLD = GOLD -P
2150 PRINT "MARCOS HANDS YOU YOUR WEAPON AND TAKES": PRINT "THE PRICE FROM YOU.": PRINT
2160 IF GOLD < FN P(50) THEN 2210
2170 PRINT "HE NOW ASKS YOU, 'NOW HOW ABOUT SOME": PRINT "ARMOUR?'": PRINT : PRINT "(HIT Y OR N) ";
2180 GET A$: IF A$ = "N" THEN PRINT A$: PRINT : GOTO 2210
2190 IF A$ < >"Y" THEN 2180
2200 PRINT A$: GOTO 2490
2210 PRINT "MARCOS SMILES AND SAYS, 'COME BACK": PRINT "AGAIN SOON!' AS HE SHOOS YOU OUT OF HIS": PRINT "SHOP.": PRINT : GOTO 100
2220 PRINT : PRINT "MARCOS ASKS YOU, 'IS THIS WEAPON YOU": PRINT "WANT TO SELL ME A STANDARD WEAPON LIKE": PRINT "I SELL? (HIT 'Y' OR 'N') ";
2230 GET A$: IF A$ = "Y" THEN 2350
2240 IF A$ < >"N" THEN 2230
2250 PRINT A$: PRINT :P = INT(50/RTIO +.5): PRINT "MARCOS SAYS, 'THEN I CAN ONLY GIVE YOU": PRINT P;" GOLD PIECES FOR IT, TAKE IT OR": PRINT "LEAVE IT!'": PRINT : PRINT "(HIT T OR L) ";
2260 GET A$: IF A$ = "L" THEN PRINT A$: PRINT : GOTO 2210
2270 IF A$ < >"T" THEN 2260
2280 PRINT A$: PRINT : PRINT "MARCOS SAYS, 'OKAY, WHAT'VE YOU GOT?": PRINT : INPUT "(ENTER THE WEAPON NAME)";W$: FOR W = 1 TO 4: IF WN$(W) < >W$ THEN NEXT : PRINT : PRINT "MARCOS FROWNS AT YOU AND SAYS, 'YOU": PRINT "CAN'T SELL A WEAPON YOU DON'T OWN!'": PRINT : GOTO 2210
2285 IF W$ = "NONE" THEN PRINT : PRINT "MARCOS FROWNS AND SAYS 'THEN WHY DO YOU WASTE MY TIME?'": PRINT : PRINT "MARCOS SHOOS YOU OUT OF HIS STORE.": GOTO 100
2290 L = LEFT$(W$,5) = "SWORD" OR LEFT$(W$,5) = "SPEAR" OR LEFT$(W$,4) = "MACE" OR LEFT$(W$,3) = "BOW" OR LEFT$(W$,3) = "AXE": IF L THEN PRINT "MARCOS FROWNS AT YOU AND SAYS, 'THIS IS": PRINT "A WEAPON LIKE I SELL, REMEMBER!'": GOTO 2420
2300 PRINT "MARCOS GIVES YOU YOUR MONEY AND TAKES": PRINT "YOUR WEAPON.": PRINT :GOLD = GOLD +P: FOR W2 = W TO 4:WN$(W2) = WN$(W2 +1):WT%(W2) = WT%(W2 +1):WO%(W2) = WO%(W2 +1):WD%(W2) = WD%(W2 +1):WS%(W2) = WS%(W2 +1): NEXT :WN$(4) = "NONE"
2310 PRINT : PRINT "MARCOS ASKS YOU, 'HOW ABOUT BUYING A": PRINT "WEAPON?'": PRINT : PRINT "(HIT Y OR N) ";
2320 GET A$: IF A$ = "Y" THEN PRINT A$: PRINT : GOTO 2050
2330 IF A$ < >"N" THEN 2320
2340 PRINT A$: PRINT : GOTO 2160
2350 PRINT : PRINT "MARCOS ASKS, 'WELL, WHAT WEAPON YOU": PRINT "WANTA RETURN?": PRINT : GOSUB 2650: PRINT
2360 W2 = W: FOR W = 1 TO 4: IF LEFT$(WN$(W), LEN(N$)) < >N$ THEN NEXT : PRINT "MARCOS LAUGHS AND SAYS, 'YOU NEVER": PRINT "BOUGHT ONE FROM ME, REMEMBER?'": PRINT : GOTO 2210
2370 BP = BP +BP *(WO%(T) >5) -BP/2 *(WO%(T) < -5):P = INT(BP/RTIO +.5): IF P >BP/4 THEN P = INT(BP/4 +.5)
2380 PRINT "MARCOS EXAMINES YOUR WEAPONS AND SAYS,": PRINT "'WELL, YOU'VE BANGED IT UP A BIT, BUT": PRINT "I CAN GIVE YOU ";P;" GOLD PIECES": PRINT "FOR IT, TAKE IT OR LEAVE IT.'": PRINT : PRINT "(HIT T OR L) ";
2390 GET A$: IF A$ = "L" THEN PRINT A$: PRINT : GOTO 2210
2400 IF A$ < >"T" THEN 2390
2410 PRINT A$: PRINT : GOTO 2300
2420 PRINT : FOR X = 1 TO 4: IF MID$ ("ABMS",X,1) = LEFT$(W$,1) THEN ON X GOTO 2440,2450,2460,2470
2430 NEXT X
2440 BP = 25: GOTO 2370
2450 BP = 40: GOTO 2370
2460 BP = 20: GOTO 2370
2470 IF MID$ (W$,2,1) = "P" THEN BP = 25: GOTO 2370
2480 BP = 50: GOTO 2370
2490 A2 = INT(AC/2):SH = AC -A2 *2:B1 = 25 *(A2 = 1) +60 *(A2 = 2) +100 *(A2 = 3):TI = INT(B1/RTIO +.5): PRINT "MARCOS TAKES YOU TO THE ARMOUR SECTION": PRINT "OF HIS SHOP AND SHOWS YOU SUITS OF": PRINT "LEATHER ARMOUR, CHAIN ARMOUR, AND PLATE.": IF TI >B1 *2 THEN TI = B1 *2
2500 PRINT : PRINT "HE SAYS, 'I CAN PUT YOU IN ANY OF THESE": PRINT "VERY CHEAPLY. I NEED "; FN P(100);" GOLD": PRINT "PIECES FOR THE LEATHER, "; FN P(250);" FOR": PRINT "THE CHAIN, AND "; FN P(500);" FOR THE PLATE.": PRINT
2510 IF TI THEN PRINT "ALSO, I CAN GIVE YOU A TRADE-IN ON YOUR": PRINT "OLD ARMOUR OF ";TI;" GOLD PIECES.": PRINT
2520 PRINT "WELL, WHAT WILL IT BE?'": PRINT : PRINT "(HIT N FOR NOTHING OR L C OR P) ";
2530 GET A$: FOR A = 1 TO 4: IF A$ < > MID$ ("NLCP",A,1) THEN NEXT : GOTO 2530
2540 PRINT A$: PRINT : IF A = 1 THEN 2570
2550 P = FN P(100 *(A = 2) +250 *(A = 3) +500 *(A = 4)) -TI: IF P >GOLD THEN PRINT "MARCOS FROWNS WHEN HE SEES THAT YOU DO": PRINT "NOT HAVE ENOUGHT TO PAY FOR YOUR": PRINT "ARMOUR AND SAYS, 'I DON'T GIVE CREDIT!'": PRINT : GOTO 2570
2560 PRINT "MARCOS TAKES YOUR OLD ARMOUR AND YOUR": PRINT "GOLD AND HELPS YOU INTO YOUR NEW": PRINT "ARMOUR.": PRINT :GOLD = GOLD -P:A2 = A -1
2570 IF SH THEN 2630
2580 PRINT "MARCOS SMILES AND SAYS, 'NOW HOW ABOUT": PRINT "A SHIELD? I CAN LET YOU HAVE ONE FOR": PRINT "ONLY "; FN P(50);" GOLD PIECES!'": PRINT : PRINT "(HIT Y OR N)";
2590 GET A$: IF A$ = "N" THEN PRINT A$: PRINT : GOTO 2630
2600 IF A$ < >"Y" THEN 2590
2610 PRINT A$: PRINT : IF GOLD < FN P(50) THEN PRINT "WHEN HE SEES THAT YOU DO NOT HAVE": PRINT "ENOUGH GOLD TO BUY THE SHIELD, MARCOS": PRINT "FROWNS AND SAYS, 'I'M SORRY, BUT I": PRINT "DON'T GIVE CREDIT!'": PRINT : GOTO 2630
2620 GOLD = GOLD - FN P(50):SH = 1: PRINT "MARCOS TAKES YOUR GOLD AND GIVES YOU": PRINT "A SHIELD.": PRINT
2630 AC = A2 *2 +SH: PRINT : GOTO 100
2640 END
2650 PRINT "(HIT THE KEY(S), A B M SP OR SW) ";:
2660 GET A$: FOR W = 1 TO 4: IF A$ < > MID$ ("ABMS",W,1) THEN NEXT : GOTO 2660
2670 ON W GOTO 2680,2690,2700,2710
2680 PRINT "AXE":BP = 25:N$ = "AXE":TP = 1:SIDE = 6: GOTO 2750
2690 PRINT "BOW":BP = 40:N$ = "BOW":TP = 2:SIDE = 6: GOTO 2750
2700 PRINT "MACE":BP = 20:N$ = "MACE":TP = 3:SIDE = 4: GOTO 2750
2710 PRINT A$;:
2720 GET A$: IF A$ = "P" THEN PRINT "PEAR":BP = 25:TP = 4:SIDE = 5:N$ = "SPEAR": GOTO 2750
2730 IF A$ < >"W" THEN 2720
2740 PRINT "WORD":BP = 50:N$ = "SWORD":TP = 5:SIDE = 8
2750 DICE = 1: RETURN
2760 END
3000 PRINT : PRINT "AFTER A FEW MINUTES DILIGENT SEARCHING,": PRINT "YOU FIND HOKAS TOKAS, THE OLD MAGE. HE": PRINT "LOOKS AT YOU AND SAYS, 'SO YOU WANT OLD": PRINT "TOKEY TO TEACH YOU SOME MAGIC, HEH HEH?"
3010 PRINT "WELL, IT'LL COST YOU. TODAY MY FEES ARE:":C2 = CH + INT(11 * RND(1) -5):C2 = C2 +(C2 = 0):RTIO = 10/C2
3020 PRINT " BLAST "; FN P(3000);"GP": PRINT " HEAL "; FN P(1000);"GP": PRINT " SPEED "; FN P(5000);"GP": PRINT " POWER "; FN P(100);"GP": PRINT
3030 PRINT "WELL, WHICH WILL IT BE?'": PRINT : PRINT "(HIT THE KEY FOR YOUR SPELL:": PRINT " N FOR NOTHING, OR B,H,S OR P) ";
3040 GET A$: FOR SP = 1 TO 5: IF A$ < > MID$ ("BHSPN",SP,1) THEN NEXT : GOTO 3040
3050 ON SP GOTO 3060,3070,3080,3090,3200
3060 PRINT "BLAST":P = FN P(3000): GOTO 3100
3070 PRINT "HEAL":P = FN P(1000): GOTO 3100
3080 PRINT "SPEED":P = FN P(5000): GOTO 3100
3090 PRINT "POWER":P = FN P(100)
3100 PRINT : IF P >GOLD THEN PRINT "WHEN HOKAS SEES THAT YOU DON'T HAVE": PRINT "ENOUGH TO PAY HIM, HE STALKS TO THE": PRINT "BAR, MUTTERING ABOUT YOUNGSTERS WHO": PRINT "SHOULD BE TURNED INTO FROGS.": PRINT : GOTO 100
3110 IF SA%(SP) THEN PRINT "HOKAS SAYS, 'I OUGHT TO TAKE YOUR": PRINT "GOLD ANYWAY, BUT HAVEN'T YOU FORGOTTEN": PRINT "SOMETHING? I ALREADY TAUGHT YOU THAT": PRINT "SPELL!'": PRINT : PRINT "SHAKING HIS HEAD SADLY, HE RETURNS TO": PRINT "BAR.": PRINT : GOTO 100
3120 GOLD = GOLD -P:SA%(SP) = INT(50 * RND(1) +26): PRINT "HOKAS TEACHES YOU YOUR SPELL, TAKES": PRINT "HIS FEE, AND RETURNS TO HIS STOOL ON": PRINT "THE BAR. AS YOU WALK AWAY YOU HEAR"
3130 PRINT "HIM ORDER A DOUBLE DRAGON BLOMB.": PRINT : GOTO 100
3140 END
3200 PRINT : PRINT : PRINT "AS YOU LEAVE, YOU HEAR HOKAS MUTTERING": PRINT "ABOUT CHEAPSKATE ADVENTURERS ALWAYS": PRINT "WANTING SOMETHING FOR NOTHING.": PRINT : GOTO 100
4000 PRINT : PRINT "YOU HAVE NO TROUBLE SPOTTING SHYLOCK": PRINT "MCFENNEY, THE LOCAL BANKER, DUE TO HIS": PRINT "LARGE BELLY.": PRINT : PRINT "YOU ATTRACT HIS ATTENTION, AND HE COMES": PRINT "OVER TO YOU AND SAYS, 'WELL,"
4010 PRINT NAME$;", MY DEAR "; MID$ ("GIRLBOY",(SEX$ = "M") *4 +1,4);",": PRINT "WHAT A PLEASURE TO SEE YOU! DO YOU WANT"
4020 PRINT "TO MAKE A DEPOSIT OR A WITHDRAWL?'": PRINT : PRINT "(HIT 'D' FOR DEPOSIT, 'W' FOR WITHDRAWL) ";
4030 GET A$: IF A$ = "D" THEN PRINT A$: PRINT : GOTO 4090
4040 IF A$ < >"W" THEN 4030
4050 PRINT A$: PRINT : PRINT "SHYLOCK SAYS, 'WELL, YOU HAVE ";BANK: PRINT "GOLD PIECES STORED WITH ME. HOW MANY": PRINT "DO YOU WANT TO TAKE BACK?'": PRINT
4060 PRINT "(ENTER THE NUMBER OF GOLD PIECES TO": INPUT " WITHDRAW) ";A$:MNY = VAL(A$): IF MNY <0 OR MNY < > INT(MNY) OR STR$(MNY) < >A$ THEN PRINT : PRINT "THE BANKER SCOWLS AND SAYS,'COME, COME,": PRINT "YOU'RE NOT MAKING SENSE! TRY AGAIN.'": PRINT : GOTO 4060
4070 IF MNY >BANK THEN PRINT : PRINT "THE BANKER THROWS YOU A TERRIBLE GLANCE": PRINT "AND SAYS, 'THAT'S MORE THAN YOU'VE GOT!": PRINT "YOU KNOW I DON'T MAKE LOANS TO YOUR": PRINT "KIND!' WITH THAT HE LOSES HIMSELF IN": PRINT "THE CROWD.": PRINT : GOTO 100
4080 GOLD = GOLD +MNY:BANK = BANK -MNY: PRINT : PRINT "THE BANKER HANDS YOU YOUR GOLD AND": PRINT "SAYS, 'THAT LEAVES YOU WITH ";BANK: PRINT "PIECES IN MY CARE.' HE SHAKES YOUR": PRINT "HAND AND WALKS AWAY.": PRINT : GOTO 100
4090 PRINT "SHYLOCK GETS A WIDE GRIN ON HIS FACE": PRINT "AND SAYS, 'GOOD FOR YOU! HOW MUCH DO": PRINT "YOU WANT TO DEPOSIT?'"
4100 PRINT : PRINT "(ENTER THE AMOUNT YOU WANT TO DEPOSIT)": INPUT " ";A$:MNY = VAL(A$): IF MNY <0 OR MNY < > INT(MNY) OR STR$(MNY) < >A$ THEN PRINT : PRINT "THE BANKER SCOWLS AT YOU AND SAYS,": PRINT "'COME, COME, YOU'RE NOT MAKING SENSE!": PRINT "TRY AGAIN.'": PRINT : GOTO 4100
4110 IF MNY >GOLD THEN PRINT : PRINT "THE BANKER WAS VERY PLEASED WHEN YOU": PRINT "TOLD HIM THE SUM, BUT WHEN HE DISCOVEREDTHAT YOU DIDN'T HAVE THAT MUCH ON YOU,": PRINT "HE WALKED AWAY, SHOUTING ABOUT FOOLS": PRINT "WHO PLAY TRICKS ON A KINDLY BANKER.": PRINT : GOTO 100
4120 GOLD = GOLD -MNY:BANK = BANK +MNY: PRINT "SHYLOCK TAKES YOUR MONEY, PUTS IT IN": PRINT "HIS BAG, LISTENS TO IT JINGLE, THEN": PRINT "THANKS YOU AND WALKS AWAY.": PRINT : GOTO 100
4130 END
5000 HOME : PRINT "YOU ARE THE "; MID$ ("MIGHTY FAIR ",1 +7 *(SEX$ = "F"),7);NAME$: PRINT : PRINT "YOUR ATTRIBUTES ARE:": PRINT " HD=";HD;" AG=";AG;" CH=";CH: PRINT
5010 PRINT "YOU KNOW THE FOLLOWING SPELLS--":SM = 0: FOR S = 1 TO 4: IF SA%(S) THEN PRINT MID$ ("BLASTHEAL SPEEDPOWER",(S -1) *5 +1,5);" ";:SM = 1
5020 NEXT S: IF NOT SM THEN PRINT " NO SPELLS";
5030 PRINT : PRINT : PRINT "YOUR WEAPON ABILITIES ARE--": PRINT " AXE BOW CLUB SPEAR SWORD": PRINT " ";: FOR W = 1 TO 5: PRINT SPC( 1 -(WA%(W) <0) +( ABS(WA%(W)) <10) +( ABS(WA%(WA)) <100));WA%(W);"% ";: NEXT : PRINT
5040 PRINT :A2 = INT(AC/2): PRINT "ARMOUR: "; MID$ ("SKIN LEATHERCHAIN PLATE ",A2 *7 +1,7);: IF AC >A2 *2 THEN PRINT " AND SHIELD";
5050 PRINT TAB( 30);"AE=";AE;"%": PRINT : PRINT "GOLD IN HAND=";GOLD;", BANK=";BANK"
5060 PRINT : PRINT "WEAPONS"; TAB( 19);"CMPLX DAM": FOR W = 1 TO 4: IF W >1 AND WN$(W) = "NONE" THEN 5090
5070 IF WN$(W) = "NONE" THEN PRINT : PRINT " NO WEAPONS": GOTO 5090
5080 PRINT WN$(W); TAB( 20 -(WO%(W) <0) +( ABS(WO%(W)) <10) +( ABS(WO%(W)) <100));WO%(W);"% ";WD%(W);" D ";WS%(W)
5090 NEXT W: VTAB 23: POKE -16368,0: PRINT "(HIT ANY KEY TO CONTINUE) ";: GET A$: PRINT : GOTO 100
5100 END
6000 PRINT "AS YOU LEAVE THE HALL, THE IRISHMAN": PRINT "COMES UP TO YOU, SLAPS YOU ON THE BACK": PRINT "AND SAYS, 'Y'ALL COME BACK REAL SOON,": PRINT "YA HEAH?'"
6010 PRINT DK$;"OPEN CHARACTERS,L150": PRINT DK$;"WRITE CHARACTERS,R";REC: GOSUB 200: PRINT DK$;"CLOSE"
6020 PRINT DK$;"DELETE THE.ADVENTURER"
6030 PRINT DK$"-EAMON.MASTER"
7000 PRINT CHR$(4);"-EAMON.MASTER"
Text found in disk135.dsk/NEW.CHARACTER.bas:
0 REM THE WONDERFUL WORLD OF
1 REM EAMON
2 REM
3 REM CHARACTER GENERATOR
4 REM AND INSTRUCTIONS
5 REM
6 REM BY DONALD BROWN
7 REM
10 DK$ = CHR$(4)
20 DEF FN R(X) = INT(X * RND(1) +1)
30 DEF FN A(X) = FN R(X) + FN R(X) + FN R(X)
40 PRINT DK$;"OPEN THE.ADVENTURER": PRINT DK$;"READ THE.ADVENTURER": INPUT NAME$: PRINT DK$;"CLOSE"
50 PRINT : PRINT "THE IRISHMAN SAYS, 'FIRST I MUST KNOW": PRINT "WHETHER YE BE MALE OR FEMALE. WHICH ARE": PRINT "YE (HIT 'M' FOR MALE, 'F' FOR FEMALE)?";
60 GET SEX$: IF SEX$ = "M" THEN 80
70 IF SEX$ < >"F" THEN 60
80 PRINT SEX$: PRINT
90 PRINT : PRINT "THE IRISHMAN WALKS AWAY AND IN WALKS A": PRINT "TALL MAN OF POSSIBLY ELVISH DESCENT.": PRINT : PRINT "HE STUDIES YOU FOR A MOMENT AND SAYS,": PRINT "'HERE IS A BOOKLET OF INSTRUCTION FOR"
100 PRINT "YOU TO READ, AND YOUR PRIME ATTRIBUTES": PRINT "ARE--": PRINT
105 VT = PEEK(37) +1
110 HD = FN A(8):AG = FN A(8):CH = FN A(8)
120 PRINT " HARDINESS--";HD: PRINT " AGILITY --";AG: PRINT " CHARISMA --";CH;"'": PRINT
122 A$ = ""
125 IF HD +AG +CH <39 THEN GOSUB 600
126 IF A$ = "Y" THEN 110
127 IF CH <10 OR HD <10 OR AG <10 THEN GOSUB 600
128 IF A$ = "Y" THEN 110
130 PRINT "(HIT 'R' TO READ INSTRUCTIONS, 'T' TO GIVE THEM BACK)";
140 GET A$: IF A$ = "T" THEN 500
150 IF A$ < >"R" THEN 140
200 PRINT : HOME : PRINT "YOU READ THE INSTRUCTIONS AND THEY SAY--": INVERSE : PRINT " INFORMATION ABOUT THE WORLD OF EAMON ": NORMAL
210 PRINT : PRINT "YOU WILL HAVE TO BUY A WEAPON. YOUR": PRINT "CHANCE TO HIT WITH IT WILL BE THE": PRINT "WEAPON COMPLEXITY, PLUS YOUR ABILITY": PRINT "IN THAT CLASS, PLUS TWICE YOUR AGILITY.": PRINT
220 PRINT "THE FIVE CLASSES OF WEAPONS (AND YOUR": PRINT "CURRENT ABILITIES WITH EACH) ARE--": PRINT " CLUB/MACE 20%": PRINT " SPEAR 10%": PRINT " AXE 5%": PRINT " SWORD 0%": PRINT " BOW -10%": PRINT
230 PRINT "EVERY TIME YOU SCORE A HIT IN BATTLE,": PRINT "YOUR ABILITY IN THE WEAPON CLASS MAY GO": PRINT "UP BY 2%, IF A RANDOM NUMBER FROM 1-100": PRINT "IS LESS THAN YOUR CHANCE TO MISS!": PRINT
240 PRINT "(HIT ANY KEY TO CONTINUE)";: GET A$: PRINT : HOME
250 PRINT "THERE ARE FOUR ARMOR TYPES, AND YOU MAY": PRINT "ALSO CARRY A SHIELD IF YOU DO NOT USE": PRINT "A TWO-HANDED WEAPON. THESE PROTECTIONS": PRINT "WILL ABSORB HITS PLACED UPON YOU(ALMOST": PRINT "ALWAYS!) BUT THEY LOWER YOUR CHANCE TO"
260 PRINT "HIT. THE PROTECTIONS ARE--": PRINT : PRINT "ARMOR"; TAB( 15);"HITS PROTECT ODDS ADJUST":: PRINT " NONE"; TAB( 18);"0"; TAB( 35);"- 0%": PRINT " LEATHER"; TAB( 18);1; TAB( 35);"-10%": PRINT " CHAIN"; TAB( 18);2; TAB( 35);"-20%"
270 PRINT " PLATE"; TAB( 18);5; TAB( 35);"-60%": PRINT " SHIELD"; TAB( 18);1; TAB( 35);"- 5%": PRINT : PRINT : PRINT "YOU WILL DEVELOP AN ARMOUR EXPERTISE,": PRINT "WHICH WILL GO UP WHEN YOU HIT A BLOW": PRINT "WEARING ARMOUR AND YOUR EXPERTISE IS": PRINT "LESS THAN THE ARMOUR YOU ARE WEARING."
280 PRINT "NO MATTER HOW HIGH YOUR ARMOUR EXPERTISEIS, HOWEVER, THE NET EFFECT OF ARMOUR": PRINT "WILL NEVER INCREASE YOUR CHANCE TO HIT.": PRINT
290 PRINT "(HIT ANY KEY TO CONTINUE) ";: GET A$: PRINT : HOME
300 PRINT : PRINT "YOU CAN CARRY WEIGHTS UP TO TEN TIMES": PRINT "YOUR HARDINESS, OR ";HD *10;" GRONDS.": PRINT "(A MEASURE OF WEIGHT, ONE GROND=10 DOS)": PRINT
310 PRINT "ADDITIONALLY, YOUR HARDINESS TELLS HOW": PRINT "MANY POINTS OF DAMAGE YOU CAN SURVIVE.": PRINT "THEREFORE, YOU CAN BE HIT WITH ";HD: PRINT "1-POINT BLOWS BEFORE YOU DIE.": PRINT
320 PRINT "HOWEVER, YOU WILL NOT BE TOLD HOW MANY": PRINT "BLOWS YOU HAVE TAKEN. YOU WILL BE": PRINT "MERELY TOLD THINGS SUCH AS": PRINT : PRINT " 'WOW! THAT ONE HURT!'": PRINT "OR 'YOU DON'T FEEL VERY WELL'": PRINT
330 PRINT "(HIT ANY KEY TO CONTINUE) ";: GET A$: PRINT : HOME
340 PRINT "YOUR CHARISMA (";CH;") AFFECTS HOW CITIZENS": PRINT "OF EAMON REACT TO YOU. YOU AFFECT A": PRINT "MONSTER'S FRIENDLINESS RATING BY YOUR": PRINT "CHARISMA LESS TEN, DIFFERENCE TIMES TWO": PRINT "(";(CH -10) *2;"%)": PRINT
350 PRINT "YOU START OFF WITH 200 GOLD PIECES,": PRINT "WHICH YOU WILL WANT TO SPEND ON SUPPLIESFOR YOUR FIRST ADVENTURE. YOU WILL GET": PRINT "A LOWER PRICE FOR ITEMS IF YOUR CHARISMAIS HIGH.": PRINT
360 PRINT "AFTER YOU BEGIN TO ACCUMULATE WEALTH,": PRINT "YOU MAY WANT TO PUT SOME OF YOUR MONEY": PRINT "INTO THE BANK, WHERE IT CANNOT BE": PRINT "STOLEN. HOWEVER, IT IS A GOOD IDEA TO": PRINT "CARRY SOME GOLD WITH YOU FOR USE IN"
370 PRINT "BARGAINING AND RANSOM SITUATIONS.": PRINT : PRINT "(HIT ANY KEY TO CONTINUE) ";: GET A$: PRINT : HOME
380 PRINT "YOU MAY ALSO HIRE A WIZARD TO TEACH YOU": PRINT "SOME MAGIC SPELLS. THERE ARE FOUR": PRINT "SPELLS YOU MAY LEARN.": PRINT : PRINT "BLAST--HURT YOUR ENEMIES FROM A DISTANCEHEAL --REMOVE DAMAGE FROM YOUR BODY.": PRINT "SPEED--DOUBLE YOUR DEXTERITY FOR A TIME"
390 PRINT "POWER--DOES SOMETHING WEIRD. THE EXACT": PRINT " EFFECT IS UNPREDICTABLE.": PRINT
400 PRINT : PRINT "OTHER TYPES OF MAGIC MAY WORK IN VARIOUSADVENTURES, AND ITEMS MAY HAVE SPECIAL": PRINT "PROPERTIES. HOWEVER, THESE WILL NOT": PRINT "WORK IN OTHER ADVENTURES THAN WHERE THEYWERE FOUND. THUS, IT IS BEST (AND YOU"
410 PRINT "HAVE NO CHOICE BUT TO) SELL ALL ITEMS": PRINT "FOUND IN ADVENTURES, EXCEPT FOR WEAPONS": PRINT "AND ARMOUR.": PRINT
420 PRINT "(HIT ANY KEY TO CONTINUE) ";: GET A$
500 PRINT : HOME : PRINT "THE MAN BEHIND THE DESK TAKES BACK THE": PRINT "INSTRUCTIONS AND SAYS, 'IT IS NOW TIME": PRINT "FOR YOU TO START YOUR LIFE.' HE MAKES": PRINT "AN ODD SIGN WITH HIS HAND AND SAYS,": PRINT "'LIVE LONG AND PROSPER.'": PRINT
510 PRINT "YOU NOW WANDER INTO THE MAIN HALL."
520 PRINT DK$;"OPEN CHARACTERS,L150": PRINT DK$;"READ CHARACTERS,R0": INPUT NC: FOR R = 1 TO NC: PRINT DK$;"READ CHARACTERS,R";R: INPUT A$: IF A$ < >"" THEN NEXT : PRINT DK$;"WRITE CHARACTERS,R0": PRINT NC +1:R = NC +1
530 PRINT DK$;"WRITE CHARACTERS,R";R: PRINT NAME$
540 PRINT HD: PRINT AG: PRINT CH: FOR X = 1 TO 4: PRINT "0": NEXT
550 PRINT "5": PRINT "-10": PRINT "20": PRINT "10": PRINT "0": PRINT "0": PRINT SEX$: PRINT "200": PRINT "0": PRINT "0"
560 FOR W = 1 TO 4: PRINT "NONE": PRINT "0": PRINT "0": PRINT "0,0": NEXT
570 PRINT DK$;"CLOSE"
580 PRINT DK$;"OPEN THE.ADVENTURER": PRINT DK$;"WRITE THE.ADVENTURER": PRINT NAME$: PRINT R: PRINT DK$;"CLOSE"
590 PRINT DK$;"RUN MAIN.HALL"
595 END
600 REM /// SUICIDE ROUTINE
610 PRINT : PRINT "YOUR CHARACTER IS SUCH A POOR EXCUSE": PRINT : PRINT "FOR AN ADVENTURER THAT WE WILL ALLOW": PRINT : PRINT "YOU TO COMMIT SUICIDE. ENTER 'Y' TO": PRINT : PRINT "COMMIT SUICIDE, ELSE 'N'";
620 GET A$: IF A$ < >"Y" AND A$ < >"N" THEN 620
630 PRINT : PRINT : IF A$ = "N" THEN RETURN
640 PRINT "WE RESSURRECT YOU AGAIN AND YOUR PRIME": PRINT : PRINT "ATTRIBUTES ARE --": PRINT
650 RETURN
Text found in disk135.dsk/REV.19SEP90.bas:
10 HOME : PRINT "EAMON ADVENTURER'S GUILD": PRINT "7625 HAWKHAVEN DR.": PRINT "CLEMMONS, NC 27012"
15 VTAB 8: HTAB 10: PRINT "EAMON ADVENTURE #001": PRINT : PRINT " -> EAMON MASTER AND BEGINNERS CAVE <-": PRINT : PRINT " BY DONALD BROWN AND JOHN NELSON"
20 VTAB 18: PRINT "LAST UPDATE: 9/19/90"
Text found in disk135.dsk/SNAPPY.txt:
9
HAVING TO WORK LATE
READERS HAVE.
BEING PULLED AWAY FROM THE BAR TO LOOK UP NAMES
ES
ISHNESS
HNESHAVING SEEN UGLY FACES BEFORE BUT NEVER ANYTHING LIKE THIS
S
D THE IDIOT ON THE OTHER SHIFT WITH THE LOUSY HANDWRITING
ING
G
HOW THE DAYS ARE SO LONG SINCE HE QUIT ADVENTURING
MES
ES
ESHOW HE ONCE WAS YOUNG AND FOOLISH TOO
AY.
WEIRD YOUNG ADVENTURERS WITH EVEN WEIRDER NAMES
G LIKE THIS.
YOUNG GREENHORNS THAT THINK THEY KNOW IT ALL
THEMSELVES.
TAKING THE BARMAID OUT AFTER HER SHIFT
D QUIT THIS BUSINESS.
THE GOOD OLD DAYS WHEN ADVENTURERS HAD SOME TRACE OF BRAINS
WISHING HE WERE STILL IN SHAPE TO GO ON ADVENTURES
NUTS THAT COYOUNG GREENHORNS WHO THINK THEY KNOW IT ALL
LEAVING THIS JOB TO START A DUNGEON
JOINING THE UNION AND NOT HAVING TO PUT UP WITH THESE YOUNG UPSTARTS
Text found in disk135.dsk/STARTUP.bas:
10 PRINT CHR$(4)"-eamon.master"
Text found in disk135.dsk/THE.ADVENTURER.txt:
JJ
2
2
- Addeddate
- 2013-10-11 09:04:31
- Collection_added
- emulation
- Emulator
- apple2ee
- Emulator_ext
- dsk
- Identifier
- ri_apple_group_crate_001_disks_135
- Scanner
- Internet Archive Python library 0.3.8
comment
Reviews
271 Views
DOWNLOAD OPTIONS
IN COLLECTIONS
Rhode Island Apple Group Floppy Disk Collection The Software Library: Apple Computer Software Library The Emulation StationUploaded by Jason Scott on